La consultazione del forum è libera per tutti.
Per poter porre un quesito è invece necessario essere un utente registrato (clicca qui se non lo sei).
Tutti gli utenti che richiedono un supporto, come da REGOLAMENTO, sono caldamente invitati ad allegare un file di esempio con l'indicazione di quello che si desidera ottenere.
Buonasera a tutti,
sono qui di nuovo alla ricerca del vostro aiuto.
Mi ritrovo nella situazione di dover creare una colonna di recap al termine di una tabella excel nella quale sia riportato il valore presente nell'ultima cella della riga e, in caso l'ultima celle sia vuota, mi riporti il valore presente nella cella precedente.
Non ho problemi quando ho solo due celle da cui pescare grazie alla formula:
=SE(VAL.VUOTO(E2);D2;E2)
Ma avrei necessità di aggiungere un'ulteriore step. Ho provato ad utilizzare una formala se annidiato ma senza successo.
Grazie a chiunque mi sarà di aiuto!
In allegato una piccola tabella esemplificativa.
ciao
matriciale CTRL MAIUSCOLO INVIO
=CERCA(2;1/($C2:$E2<>"");$C2:$E2)
oppure........ma vale solo per i numeri
=INDICE($C2:$E2;CONFRONTA(111111;$C2:$E2;1))
Ciao Gianfranco,
grazie mille. Funziona alla grande.
Potrei chiederti un'ulteriore integrazione a questa formula? Metti infatti caso che all'interno della tabella ci siano delle colonne con dati che non devo considerare.
Ti allego il solito file esempio dato che a parole sento di non essermi spiegato bene.
Grazie Mille ancora!
Mattia
ciao
mi dovresti fare degli esempi
nel tuo basta escludere la colonna C
solo colonne dispari visto che nelle pari ci sono altri dati
=CERCA(2;1/($C2:$G2<>"")/(VAL.DISPARI(RIF.COLONNA($C$1:$G$1)));$C2:$G2)
Ciao Gianfranco,
mi rendo conto che era difficile spiegarmi. Per tagliare la testa al toro in allegato una tabella rielaborata da quella su cui sto lavorando.
In pratica ad ogni riga corrisponde una persona con la combinazione di treni (o altri mezzi) che dovrà prendere per raggiungere la sua destinazione con tanto di orari di partenza, arrivo e numero di treno.
In alcuni casi basta un treno in altri è necessario un cambio o più di un cambio.
Nelle ultime due colonne sto cercando di riportarmi esclusivamente l'orario di arrivo a destinazione il numero del treno finale.
Avrei quindi bisogno di una formula che andasse a pescare dall'ultima colonna arrival (o number) con presente dei dati.
Spero questa volta di essermi spiegato meglio.
Come sempre grazie di cuore!
Mattia
ciao
in V4
=SE.ERRORE(CERCA(2;1/(($D4:$U4<>"")*($D$3:$U$3=V$3));$D4:$U4);"")
in W4
=SE.ERRORE(CERCA(2;1/($D4:$U4>0);$D4:$U4);"")
oppure queste che dovrebbero funzionare senza confermare matriciale
=SE($B4="";"";INDICE($D4:$U4;INDICE(MAX(SE(($D$3:$U$3="NUMBER")*($D4:$U4<>"");RIF.COLONNA($D$1:$U$1)-3));;)))
=SE($B4="";"";INDICE($D4:$U4;INDICE(MAX(SE(($D$3:$U$3="ARR:")*($D4:$U4<>"");RIF.COLONNA($D$1:$U$1)-3));;)))
GRAZIE GIANFRANCO!
Eccezionale davvero!
ciao
grazie per il riscontro
ora chiudo io la discussione
la prossima volta gentilmente chiudila tu
