fbpx

MATR.SOMMA.PRODOTTO – Scheda tecnica

MATR.SOMMA.PRODOTTO

SCOPO
Moltiplicare, poi sommare matrici
SINTASSI
MATR.SOMMA.PRODOTTO(matrice1; [matrice2]; [matrice3]; ...)
ARGOMENTI DELLA FUNZIONE
  • matrice1 – La prima matrice o intervallo da moltiplicare, quindi sommare
  • matrice2 – [opzionale] La seconda matrice o intervallo da moltiplicare, quindi sommare
  • matrice3 – [opzionale] La terza matrice o intervallo da moltiplicare, quindi sommare
NOTE DI UTILIZZO

La funzione MATR.SOMMA.PRODOTTO opera con le matrici, ma non richiede di essere inserita con la normale modalità per le matrici (Ctrl + Maiusc + Invio). Lo scopo della funzione MATR.SOMMA.PRODOTTO è moltiplicare, poi sommare, matrici. Se viene fornita una sola matrice, MATR.SOMMA.PRODOTTO semplicemente somma gli elementi di quella matrice. Possono essere fornite fino a 30 matrici.

La prima volta che incontrate MATR.SOMMA.PRODOTTO, può sembrare noiosa, complessa, e anche inutile. Ma MATR.SOMMA.PRODOTTO è una funzione incredibilmente versatile con molti possibili utilizzi. Poiché è in grado di gestire le matrici con grazia e senza lamentarsi, è possibile utilizzarla per elaborare intervalli di celle in molti modi intelligenti ed eleganti (vedi link a esempi di utilizzo in questa pagina).

Per mostrare come funziona MATR.SOMMA.PRODOTTO, ecco alcuni esempi comuni.

MATR.SOMMA.PRODOTTO per conteggi e somme condizionali

Supponiamo di avere dei dati di vendita in A2:B6, con la Provincia in colonna A e le vendite in colonna B:

AB
1ProvinciaVendite
2MI75
3BG100
4SO125
5BG125
6SO150

Utilizzando MATR.SOMMA.PRODOTTO, potete contare le vendite totali per la provincia di Sondrio (“SO”) con la seguente formula:

=MATR.SOMMA.PRODOTTO(--(A2:A6="SO"))

E potete sommare le vendite totali per la provincia di Sondrio (“SO”) con la seguente formula:

=MATR.SOMMA.PRODOTTO(--(A2:A6="SO");B2:B6)

Nota: Non siate confusi dal doppio-negativo. Questo è un trucco comunemente usato nelle formule più avanzate di Excel per convertire i valori VERO e FALSO in 1 e 0. Leggete più in basso …

Per quanto riguarda l’esempio della somma qua sopra, ecco una rappresentazione di come sarebbero le due matrici dopo un primo passaggio con MATR.SOMMA.PRODOTTO

Matrice1Matrice2
FALSO75
FALSO100
VERO125
FALSO125
VERO150

Ogni matrice ha 5 elementi. La prima matrice contiene i valori VERO/FALSO che derivano dall’espressione A2:A6 =”SO”, e la seconda matrice è il contenuto di B2:B6. Ogni elemento della prima serie sarà moltiplicato per la voce corrispondente nella seconda matrice. Tuttavia, allo stato attuale, il risultato di MATR.SOMMA.PRODOTTO sarà zero perché i valori VERO e FALSO saranno trattati come zero. Abbiamo bisogno che gli elementi in matrice1 siano numerici – devono essere convertiti in 1 e 0. Qui è dove entra in gioco il doppio negativo (doppio unario).

Usando il doppio unario possiamo convertire i valori VERO/FALSO nei valori numerici uno e zero, come mostrato di seguito. L’ultima colonna “Prodotto” rappresenta il risultato della moltiplicazione delle due matrici. Il risultato sommato, 275, è il valore che MATR.SOMMA.PRODOTTO restituisce.

Matrice1Matrice2Prodotto
0* 75= 0
0* 100= 0
1* 125= 125
0* 125= 0
1* 150= 150
Somma275

Utilizzando la sintassi con le parentesi graffa usata per le matrici, l’esempio si presenta così dopo la “forzatura”:

=MATR.SOMMA.PRODOTTO({0.0.1.0.1};{75.100.125.125.150})

e così dopo la moltiplicazione

=MATR.SOMMA.PRODOTTO({0.0.125.0.150})

MATR.SOMMA.PRODOTTO con altre funzioni

MATR.SOMMA.PRODOTTO può usare direttamente anche altre funzioni. Potreste vedere MATR.SOMMA.PRODOTTO utilizzata con la funzione LUNGHEZZA per contare i caratteri totali in un intervallo, o con funzioni come VAL.VUOTO, VAL.TESTO, ecc. Queste non sono normalmente funzioni di matrice, ma quando viene data loro un’intervallo, creano un “risultato matrice”. Poiché MATR.SOMMA.PRODOTTO è costruita per lavorare con le matrici, è capace di eseguire calcoli sulle matrici direttamente. Questo può essere un buon modo per risparmiare spazio in un foglio di lavoro, eliminando la necessità di una colonna “di supporto”.

Ad esempio, supponete di avere 10 diversi valori di testo in A1:A10 e che volete contare i caratteri totali per tutti i 10 valori. Potreste aggiungere una colonna “di supporto”, ad esempio in colonna B, che utilizzi questa formula: LUNGHEZZA(A1) per calcolare il numero dei caratteri in ogni cella. A quel punto potreste utilizzare SOMMA per sommare tutti i 10 numeri. Tuttavia, utilizzando MATR.SOMMA.PRODOTTO, è possibile scrivere una formula come questa:

=MATR.SOMMA.PRODOTTO(LUNGHEZZA(A1:A10))

Quando viene utilizzata con un intervallo come A1:A10, LUNGHEZZA restituisce una matrice di 10 valori. Poi MATR.SOMMA.PRODOTTO semplicemente somma tutti i valori e restituisce il risultato, senza la necessità di una colonna di supporto.

Leggete gli esempi qui sotto, altri modi per utilizzare MATR.SOMMA.PRODOTTO.

Note:

  • MATR.SOMMA.PRODOTTO tratta gli elementi non numerici, eventualmente presenti in una matrice, come zeri
  • Le matrici fornite come argomenti devono avere la stessa dimensione. In caso contrario, MATR.SOMMA.PRODOTTO genererà un valore di errore #VALORE!
  • I test logici all’interno di una matrice creeranno valori VERO e FALSO. Nella maggior parte dei casi, ti consigliamo di convertirli in 1 e 0
  • MATR.SOMMA.PRODOTTO spesso può usare il risultato di altre funzioni direttamente (si vedano gli esempi di formule a seguire)
LINK AD APPROFONDIMENTI E/O ESEMPI DI UTILIZZO
SCHERMATE ESEMPLIFICATIVE

 

ERRORI
  • #VALORE! – Si verifica se le matrici fornite hanno dimensioni diverse.
FUNZIONI CORRELATE
  • Posts not found
  • Posts not found
LINK ALLA GUIDA IN LINEA DI OFFICE

Aspetta! Potrebbe interessarti anche: