fbpx

#Excel – Come usare CONTA.PIÙ.SE e CONTA.SE con più di un criterio

Di tutte le funzioni di Excel, CONTA.PIÙ.SE e CONTA.SE sono probabilmente il più delle volte confuse perché sembrano molto simili ed entrambe sono deputate al conteggio delle celle in base a criteri specificati.

La differenza è che la funzione CONTA.SE è destinata al conteggio delle celle di un intervallo sulla base di una singola condizione, mentre CONTA.PIÙ.SE permette di utilizzare diversi criteri. In pratica, tuttavia, con gli stessi risultati è possibile utilizzare anche CONTA.SE con criteri multipli. Quindi, l’obiettivo di questo tutorial è quello di aiutare a capire la formula più efficace per ogni attività particolare.

La funzione CONTA.PIÙ.SE – Sintassi e utilizzo

Come ho già detto, la funzione di Excel CONTA.PIÙ.SE nasce per contare le celle in più intervalli in base a una o più condizioni. La funzione CONTA.PIÙ.SE è disponibile in Excel 2016, 2013, 2010 e Excel 2007, potrete quindi utilizzare gli esempi qui sotto in qualsiasi versione moderna di Excel.

Sintassi della funzione CONTA.PIÙ.SE

La sintassi della funzione CONTA.PIÙ.SE è la seguente:

CONTA.PIÙ.SE(intervallo_criteri1; criteri1; [intervallo_criteri2; criteri2]…)
  • intervallo_criteri1: definisce il primo intervallo a cui si applica la prima condizione (criteri1). Argomento richiesto.
  • criteri1: imposta la condizione nella forma di un numero, un riferimento di cella, una stringa di testo, un’espressione o un’altra funzione di Excel. Argomento richiesto. Il criterio definisce quali celle debbano essere contate e può essere espresso come 10, “<= 32”, A6, “dolci”.
  • [intervallo_criteri2; criteri2]: questi sono intervalli supplementari ed i loro criteri associati. Sono argomenti opzionali. È possibile specificare fino a 127 coppie intervallo/criterio nelle formule.

In realtà, non c’è bisogno che ricordiate la sintassi della funzione CONTA.PIÙ.SE a memoria. Così come con qualsiasi altra formula, Microsoft Excel visualizzerà gli argomenti della funzione non appena iniziate a digitarla; mano a mano che si inseriscono gli argomenti, quello corrente è evidenziato in grassetto.

La sintassi della funzione di Excel CONTA.PIU.SE

CONTA.PIÙ.SE – Punti di attenzione!

  • Potete utilizzare la funzione CONTA.PIÙ.SE per contare sia celle in un unico intervallo con una sola condizione sia in diversi intervalli con condizioni multiple. Se si contano le ultime, solo le celle che soddisfano tutte le condizioni specificate saranno contate.
  • Ogni intervallo aggiuntivo deve avere lo stesso numero di righe e colonne del primo intervallo (argomento intervallo_criteri1).
  • Sono ammessi sia intervalli contigui che non contigui.
  • Se il criterio è un riferimento ad una cella vuota, la funzione CONTA.PIÙ.SE la tratterà come se avesse valore zero (0).
  • Nei criteri è possibile utilizzare i caratteri jolly “asterisco” (*) e “punto interrogativo” (?). Consultate questo esempio per tutti i dettagli.

Per la descrizione dettagliata e la sintassi della funzione CONTA.SE, vi invitiamo a consultare questo tutorial sulla funzione di Excel CONTA.SE.

Come utilizzare CONTA.PIÙ.SE e CONTA.SE con criteri multipli in Excel

Di seguito troverete una serie di esempi di formule che illustrano come utilizzare le funzioni CONTA.PIÙ.SE e CONTA.SE per gestire più condizioni e intervalli.

CONTA.PIÙ.SE e CONTA.SE (con criteri multipli) per i numeri

In generale, le formule CONTA.PIÙ.SE per i numeri si dividono in 2 categorie: il conteggio di numeri tra due valori specificati, e sulla base di una serie di condizioni.

Esempio 1. Contare i numeri tra X e Y

È possibile contare quante sono le celle tra i numeri specificati in due modi: utilizzando una funzione CONTA.PIÙ.SE o facendo una sottrazione tra due funzioni CONTA.SE.

Formula CONTA.PIÙ.SE: =CONTA.PIÙ.SE(C2:C10; ">5"; C2:C10; "<10")

Questa formula conta quanti numeri tra 5 e 10 (esclusi 5 e 10) sono contenuti nelle celle C2-C10.

Una formula CONTA.PIU.SE per contare i numeri tra X e Y

Se volete contare le celle in base alla stessa condizione, comprendendo anche 5 e 10, aggiungete “=” ai criteri, in questo modo: =CONTA.PIÙ.SE(C2:C10; “>=5”; C2:C10; “<=10”).

Formule CONTA.SE per contare numeri compresi tra X e Y:

  • =CONTA.SE(C2:C10; “>5”) – CONTA.SE(C2:C10; “>=10”): conta quanti numeri maggiori di 5 e minori di 10 sono nell’intervallo C2:C10. La formula produrrà lo stesso risultato dell’immagine qui sopra;
  • =CONTA.SE(C2:C10; “>=5”) – CONTA.SE(C2:C10; “>10”): la formula conta quanti numeri tra 5 e 10 sono nell’intervallo C2:C10, compresi 5 e 10.

Riassumendo, si utilizza una combinazione di due funzioni CONTA.SE nel modo seguente. Nella 1^ funzione, si contano quanti numeri sono superiori al limite inferiore (5 in questo esempio). Nella 2^ funzione, si contano quanti numeri sono superiori al limite superiore (10 nel nostro caso). La differenza tra il primo e il secondo numero è il risultato che state cercando.

Esempio 2. Contare numeri in base a criteri multipli (logica E)

La funzione CONTA.PIÙ.SE in Excel è stata progettata per contare solo quelle celle per le quali tutte le condizioni specificate sono vere. Noi la chiamiamo “logica E”, perché la funzione E di Excel funziona in questo modo.

Supponiamo che abbiate un elenco di prodotti con l’indicazione, per ognuno, delle quantità vendute, consegnate e in magazzino. È possibile utilizzare le seguenti formule per contare il numero di prodotti per i quali almeno una unità è stata venduta e consegnata, vale a dire quelli per i quali le colonne B e D sono maggiori di 0:

=CONTA.PIÙ.SE(B2:B11; ">0"; D2:D11;">0")

Una formula CONTA.PIU.SE per contare i numeri in base a criteri multipli

Ecco un altro esempio di formula CONTA.PIÙ.SE con più intervalli:

=CONTA.PIÙ.SE(B2:B11; 0; C2:C11; 0; D2:D11; 0)

La formula qui sopra conta il numero di prodotti con uno zero nelle colonne B, C e D. Questa formula CONTA.PIÙ.SE restituisce 1 perché solo Prodotto 8 ha “0” in tutte le tre colonne.

ATTENZIONE
Abbiamo bisogno di utilizzare tre intervalli distinti nella formula, uno per colonna, per contare i prodotti che contengono “0” in tutte le colonne. Una formula più semplice con un solo intervallo =CONTA.PIÙ.SE(B2:D11; “= 0”) produrrebbe un risultato diverso perché restituirebbe il conteggio totale delle celle contenenti uno zero.

Esempio 3. Come usare i riferimenti di cella nelle formule CONTA.PIÙ.SE

Naturalmente, è possibile utilizzare un riferimento di cella al posto di un numero nelle formule CONTA.PIÙ.SE. Basta ricordarsi di racchiudere l’operatore tra virgolette (“”) e aggiungere una “e commerciale” (&) prima del riferimento di cella per costruire una stringa di testo. Per ulteriori informazioni circa l’uso della “e commerciale” nelle formule CONTA.SE e CONTA.PIÙ.SE, vedete le FAQ della funzione CONTA.SE.

Quindi, facciamo una formula CONTA.PIÙ.SE con un riferimento di cella, equivalente alla formula dell’esempio precedente:

=CONTA.PIÙ.SE(B2:B11; "="&B9; C2:C11; "="&B9; D2:D11; "="&B9)

La cella B9 utilizzata nei criteri contiene un valore pari a zero, quindi la formula produrrà esattamente lo stesso risultato che vedete nello screenshot qui sopra.

Esempio 4. Formule CONTA.SE con logica O

Gli esempi 2 e 3 qui sopra dimostrano come utilizzare CONTA.PIÙ.SE per contare le celle ad una serie di condizioni con logica E, cioè quando vengono soddisfatti tutti i criteri. Tali formule possono essere applicate sia ad intervalli contigui che a quelli non contigui. Ad esempio, abbiamo utilizzato la formula =CONTA.PIÙ.SE(B2:B11; “> 0”; D2:D11; “> 0”) per scoprire quanti prodotti abbiano un valore maggiore di “0”, sia nella colonna B che nella colonna D.

E se invece volessimo il conteggio totale delle celle con un certo valore presenti in diversi intervalli non adiacenti oppure quando almeno una delle condizioni è soddisfatta (ragionando quindi con una logica O)? Per esempio, come si fa a contare il numero totale di valori “zero” nelle colonne B e D? La soluzione risiede nell’utilizzo di una combinazione, ovvero la somma di diverse funzioni CONTA.SE:

=CONTA.SE(B2:B11;"=0") + CONTA.SE(D2:D11; "=0")

Una formula CONTA.SE per contare valori numerici in intervalli non contigui

In modo simile, si possono sommare diverse funzioni CONTA.PIÙ.SE se si vuole contare qualcosa con la logica O. Ad esempio, la seguente formula conta il numero di righe che hanno “Prodotto 1” o “Prodotto 2” in colonna A e 0 in colonna B:

=CONTA.PIÙ.SE(A2:A11; "Prodotto 1"; B2:B11; 0) + CONTA.PIÙ.SE(A2:A11; "Prodotto 2"; B2:B11; 0)

CONTA.PIÙ.SE e CONTA.SE (con criteri multipli) per le date

Le formule CONTA.PIÙ.SE e CONTA.SE da utilizzare per le date sono molto simili alle formule utilizzate qui sopra per i numeri.

Esempio 1. Contare le date comprese in un determinato intervallo

Per contare le date che rientrano in un determinato intervallo di date, è possibile utilizzare una formula CONTA.PIÙ.SE con due criteri o una combinazione di due funzioni CONTA.SE.

Ad esempio, le seguenti formule contano il numero delle date nelle celle C2-C10 che rientrano tra il 1-giu-2016 e il 7-giu-2016, inclusi:

=CONTA.PIÙ.SE(C2:C9; ">=1/6/2016"; C2:C9; "<=7/6/2016")

=CONTA.SE(C2:C9; ">=1/6/2016") - CONTA.SE(C2:C9; ">7/6/2016")

La formula CONTA.SE con due condizioni per contare le date entro un intervallo

Esempio 2. Contare date con condizioni multiple

Allo stesso modo, è possibile utilizzare una formula CONTA.PIÙ.SE per contare il numero di date in diverse colonne che soddisfano 2 o più condizioni. Ad esempio, la formula di seguito scoprirà quanti prodotti sono stati acquistati dopo il 20 maggio e consegnati dopo il 1° giugno:

=CONTA.PIÙ.SE(C2:C11; ">20/5/2016"; D2:D11; ">1/6/2016")

La formula CONTA.SE per contare le date che soddisfano condizioni multiple

Esempio 3. Contare date contare con condizioni multiple in base alla data corrente

È possibile utilizzare la funzione di Excel OGGI() in combinazione con CONTA.SE per contare le date in base alla data corrente.

Ad esempio, la seguente formula CONTA.SE con due intervalli e due criteri vi dirà quanti prodotti sono già stati acquistati ma non ancora consegnati.

=CONTA.PIÙ.SE(C2:C11; "<"&OGGI(); D2:D11; ">"&OGGI())

La funzione CONTA.SE per contare date con condizioni multiple basate sulla data corrente

Questa formula permette molte possibili varianti. Per esempio, è possibile modificarla per contare quanti prodotti sono stati acquistati più di una settimana fa e non ancora consegnati:

=CONTA.PIÙ.SE(C2:C11; "<="&OGGI()-7; D2:D11; ">"&OGGI())

Formule CONTA.PIÙ.SE per i valori di testo

Nell’articolo precedente, ho fornito un esempio di formula CONTA.SE con due criteri per contare il numero di celle con 2 diversi valori di testo in un singolo intervallo. Ora vediamo come è possibile utilizzare la funzione CONTA.PIÙ.SE con criteri multipli e all’interno di più intervalli.

Esempio 1. CONTA.PIÙ.SE per i valori di testo

Supponiamo di avere una tabella che elenchi i risultati degli esami superati da parte degli studenti. Vogliamo sapere quanti studenti abbiano superato tutti gli esami. Per fare questo, si utilizza la solita formula CONTA.PIÙ.SE con diversi intervalli e criteri:

=CONTA.PIÙ.SE(C2:C7; "=P"; D2:D7; "=P"; E2:E7; "=P"; F2:F7; "=P")

Una formula CONTA.PIU.SE con diversi intervalli e lo stesso criterio

Se volete sapere quanti esami abbia superato o meno un singolo studente, è possibile utilizzare sia una formula CONTA.PIÙ.SE sia una formula CONTA.SE, perché questa volta è necessario un singolo intervallo.

Ad esempio, le formule seguenti vi diranno quanti esami ha superato Sara:

=CONTA.PIÙ.SE(B3:F3; "=P")

=CONTA.SE(B3:F3; "=P")

Esempio 2. CONTA.PIÙ.SE con caratteri jolly

Come ho detto all’inizio di questo tutorial, è possibile utilizzare i seguenti caratteri jolly nelle formule CONTA.PIÙ.SE di Excel:

  • Punto interrogativo (?) – corrisponde a qualsiasi singolo carattere, usatelo per contare le celle che iniziano o terminano con determinati caratteri;
  • Asterisco (*) – corrisponde a qualsiasi sequenza di caratteri, lo si usa per contare le celle che contengono una parola specifica o un carattere come parte del contenuto della cella.
INFO
Se effettivamente avete necessità di contare le celle con un punto interrogativo o un asterisco, digitate una tilde (~) prima del carattere nella formula CONTA.PIÙ.SE.

Ora vediamo come sia possibile utilizzare un carattere jolly nelle formule CONTA.PIÙ.SE in Excel. Supponiamo di avere un elenco di progetti assegnati ai dipendenti della vostra azienda. Volete trovare quanti progetti siano stati già assegnati a qualcuno, vale a dire che un nome qualsiasi è indicato nella colonna A. E siccome stiamo imparando ad utilizzare la funzione CONTA.PIÙ.SE con criteri multipli, aggiungiamo una seconda condizione: anche la data di fine in colonna D deve essere impostata.

Ecco la formula da utilizzare: =CONTA.PIÙ.SE(C2:C10; “*”; E2:E10; “<>”&””)

Vi invitiamo a notare che non è possibile utilizzare un criterio con carattere jolly con il secondo intervallo perché nella colonna D sono presenti date e non stringhe di testo. Per questo motivo, è necessario utilizzare un criterio che trovi le celle non vuote (“<>” & “”).

La formula CONTA.PIU.SE che conti i record con un qualsiasi testo in una colonna e celle non vuote in un altra colonna

 

ATTENZIONE
Quando si usa una formula CONTA.PIÙ.SE con più intervalli, è importante ricordare che tutti gli intervalli devono essere della stessa dimensione, cioè dello stesso numero di righe e colonne. In caso contrario, la formula restituirà l’errore #VALORE!. Questo vale per tutte le formule CONTA.PIÙ.SE in Excel, con qualsiasi tipo di dati: numeri, date e testo.

Aspetta! Potrebbe interessarti anche: