fbpx

CONTA.SE: contare le celle non vuote, maggiori di, duplicate o univoche in #Excel

Microsoft Excel fornisce diverse funzioni adatte al conteggio di diversi tipi di celle, come quelle vuote o non-vuote, con valori numerici, di data o di testo, che contengano parole o caratteri specifici, ecc.

In questo articolo, ci concentreremo sulla funzione di Excel CONTA.SE che ha lo scopo di contare le celle che soddisfano la condizione specificata. Prima ci occuperemo brevemente della sintassi e dell’utilizzo generale, e poi forniremo una serie di esempi e vi metteremo in guardia sulle possibili stranezze che si potrebbero verificare quando si utilizza questa funzione con criteri multipli e specifici tipi di celle.

In sostanza, le formule CONTA.SE sono identiche in tutte le versioni di Excel, pertanto potrete utilizzare gli esempi di questo tutorial in Excel 2016, 2013, 2010, 2007 e 2003.

La funzione CONTA.SE in Excel – Sintassi e uso

La funzione CONTA.SE di Excel viene utilizzata per il conteggio delle celle che, all’interno di un intervallo specificato, soddisfano un certo criterio o condizione.

Ad esempio, è possibile scrivere una formula CONTA.SE per scoprire quante celle nel foglio di lavoro contengano un numero maggiore o minore del numero specificato. Un altro uso tipico di CONTA.SE in Excel è per il conteggio delle celle con una determinata parola o che iniziano con una particolare lettera.

La sintassi della funzione CONTA.SE è molto semplice:

CONTA.SE(intervallo; criteri)

Come vedete, ci sono solo 2 argomenti, entrambi i quali sono necessari:

  • intervallo: definisce una o più celle da contare. Si inserisce all’interno della formula come si fa di solito in Excel, ad esempio: A1:A20
  • criteri: definisce la condizione che indica alla funzione quali celle contare. Può essere un numero, una stringa di testo, un riferimento di cella o un’espressione. Per esempio, è possibile utilizzare criteri di come questi: “10”, A2, “> = 10”, “un testo”

Questo è un semplice esempio di funzione CONTA.SE al lavoro. Quella che vedete nell’immagine qui sotto è l’elenco delle squadre vincitrici del campionato di Serie A negli ultimi 25 anni. La formula =CONTA.SE(C2:C26; “Milan”) conta quante volte il Milan è nell’elenco:

un-esempio-di-funzione-conta-se-di-excel

INFO
L’argomento criterio è case insensitive, il che significa che digitare “Milan”, “milan” oppure “MILAN” come criterio nella formula di cui sopra, produrrebbe lo stesso risultato.

Esempi di formule CONTA.SE

Come avete appena visto, la sintassi della funzione CONTA.SE è molto semplice. Tuttavia, consente tante possibili variazioni, comprese l’utilizzo di caratteri jolly, l’utilizzo di valori di altre celle o anche di altre funzioni di Excel. Questa varietà rende la funzione CONTA.SE davvero potente e adatta a molti compiti, come si vedrà negli esempi che seguono.

Formula CONTA.SE per testo e numeri (corrispondenza esatta)

In realtà, abbiamo mostrato la funzione CONTA.SE che conta valori di testo corrispondenti ad un criterio specificato esattamente un momento fa. Vi ricordo la formula:

=CONTA.SE(C2:C26; "Milan")

Sicché occorre inserire:

  • Un intervallo come primo parametro;
  • Un punto e virgola come delimitatore;
  • Una parola o più parole racchiuse tra virgolette, come criterio.

Invece di digitare il testo, è possibile utilizzare un riferimento a una cella che contiene una determinata parola o le parole e ottenere assolutamente gli stessi risultati, per esempio =CONTA.SE(C1:C9; C7).

Formule CONTA.SE come queste funzionano sia per i numeri che per i valori di testo. Come si può vedere nella schermata qui sotto, la formula =CONTA.SE(C2:C10; 7) conta perfettamente le celle con quantità 7 in colonna C.

formula-conta-se-per-i-numeri

Formule CONTA.SE con caratteri jolly (corrispondenza parziale)

Nel caso in cui i dati di Excel comprendessero diverse varianti della parola chiave che si desidera contare, è possibile utilizzare un carattere jolly per contare tutte le celle che contengono una parola, una frase o alcune lettere come parte del contenuto della cella.

Supponiamo di avere un elenco di compiti assegnati a persone diverse, e che vogliamo conoscere il numero di compiti assegnati a Peppe Verdi. Poiché il nome Peppe può essere scritto in diversi modi, inseriamo “*Verdi*”, come criterio di ricerca =CONTA.SE(C2:C10; “*Verdi*”).

una-formula-conta-se-con-caratteri-jolly-per-una-corrispondenza-parziale

 

Un asterisco (*) è utilizzato per trovare celle con qualsiasi sequenza di caratteri iniziale o finale, come illustrato nell’esempio precedente. Se vi servisse cercare un singolo carattere, inserite invece un punto interrogativo (?), come illustrato di seguito.

Contare celle che cominciano o finiscono con determinati caratteri

È possibile utilizzare il carattere jolly, asterisco (*) o punto interrogativo (?), come criterio a seconda di quale risultato si voglia esattamente raggiungere.

Se volete conoscere il numero di celle che iniziano o terminano con un determinato testo, non importa quanti caratteri una cella contenga, utilizzate queste formule:

  • =CONTA.SE(C2:C10; “Sig*”) – per contare le celle che iniziano per “Sig”
  • =CONTA.SE(C2:C10; “*to”) – per contare le celle che finiscono per “to”

Se avete necessità di contare le celle che iniziano o terminano con determinati lettere, ma che contengano un numero esatto di caratteri, è possibile utilizzare la funzione CONTA.SE assieme al punto interrogativo (?):

  • =CONTA.SE(C2:C10; “?????to”) – conta il numero di celle, nell’intervallo C2:C10, che terminano con le lettere “to” e che abbiano esattamente 7 caratteri, inclusi gli spazi.
  • =CONTA.SE(C2:C10; “Sig???????”) – conta il numero di celle, nell’intervallo C2:C10, che iniziano con le lettere “Sig” e che abbiano esattamente 10 caratteri, inclusi gli spazi.
INFO
Per trovare il numero di celle che contengono effettivamente un punto interrogativo o un asterisco, occorre digitare una tilde (~) prima dei caratteri ? o * nella formula. Ad esempio, la formula =CONTA.SE(C2:C10; “*~?*”) conterà tutte le celle che contengono il punto di domanda nell’intervallo C2:C10

CONTA.SE per celle vuote e non vuote

Questi formule di esempio dimostrano come sia possibile utilizzare la funzione CONTA.SE in Excel per contare il numero di celle vuote o non vuote in un intervallo specificato.

CONTA.SE non vuote

In alcuni altri tutorial sulla funzione CONTA.SE di Excel, potreste trovare utilizzata questa formula per il conteggio delle celle non vuote:

=CONTA.SE(intervallo; "*")

Ma purtroppo la formula qui sopra conta tutte le celle che contengono del testo, il che significa che le celle con date e numeri verranno trattate come celle vuote!

Se avete bisogno di una formula CONTA.SE universale per contare tutte le celle non vuote in un intervallo specificato, eccola:

=CONTA.SE(intervallo; "<>"&"")

Questa formula funziona correttamente con tutti i tipi di valore: testo, date e numeri.

CONTA.SE vuote

Se volete il contrario, cioè contare le celle vuote in un certo intervallo, dovreste rispettare lo stesso approccio.

Formula per contare le celle che non contengono alcun testo=CONTA.SE(intervallo; “<>”&”*”)

Traducendo in parole povere i criteri utilizzati nella formula di cui sopra ( “<>” & “*”), significa trovare celle diverse da *, vale a dire che non contengono alcun testo nell’intervallo specificato.

Formula CONTA.SE universale per le celle vuote (tutti i tipi di valore): =CONTA.SE(intervallo;””)

La formula di cui sopra gestisce correttamente i numeri, le date e i valori di testo. Ad esempio, la formula =CONTA.SE(C2:C11; “”) restituisce il numero di tutte le celle vuote nell’intervallo C2:C11.

INFO
Sappiate che Microsoft Excel fornisce un’altra funzione per il conteggio delle celle vuote =CONTA.VUOTE(intervallo). Per esempio, le formule seguenti produrranno esattamente gli stessi risultati delle formule CONTA.SE che abbiamo visto finora:

  • Contare le celle vuote: =CONTA.VUOTE(C2:C11)
  • Contare le celle non vuote: =RIGHE(C2:C11)*COLONNE(C2:C11)-CONTA.VUOTE(C2:C11)

Inoltre, tenete a mente che sia =CONTA.SE(intervallo; “”) che =CONTA.VUOTE(intervallo) contano anche le celle contenenti formule il cui risultato è una stringa vuota(“”). Se non volete trattare tali celle come spazi vuoti, usate al loro posto questa formula: =RIGHE(C2:С11)*COLONNE(C2:С11)-CONTA.SE(C2:С11;”<>”&””).

CONTA.SE maggiore, minore o uguale a

Per contare le celle con valori maggiori, minori o uguali ad un numero specificato, è sufficiente aggiungere l’operatore corrispondente ai criteri, come mostrato nella tabella sottostante.

Ricordatevi però che nelle formule CONTA.SE, un operatore con un numero sono sempre racchiusi tra virgolette.

CriterioFormula di esempioDescrizione
Conta se maggiore di=CONTA.SE(A2:A10; “>5”)Conta le celle il cui valore è maggiore di 5.
Conta se minore di=CONTA.SE(A2:A10; “<5”)Conta le celle il cui valore è minore di 5.
Conta se uguale a=CONTA.SE(A2:A10; “=5”)Conta le celle il cui valore è uguale a 5.
Conta se diverso da=CONTA.SE(A2:A10; “<>5”)Conta le celle il cui valore è diverso da 5.
Conta se maggiore o uguale a=CONTA.SE(A2:A10; “>=5”)Conta le celle il cui valore è maggiore o uguale a 5.
Conta se minore o uguale a=CONTA.SE(A2:A10; “<=5”)Conta le celle il cui valore è minore o uguale a 5.

È inoltre possibile utilizzare tutte le formule di cui sopra per contare le celle basate sul valore di un’altra cella, dovrete semplicemente sostituire il numero nei criteri con un riferimento di cella.

INFO
Nel caso utilizzaste un riferimento di cella, è necessario racchiudere l’operatore tra virgolette e aggiungere una e commerciale (&) prima del riferimento di cella. Ad esempio, per contare le celle dell’intervallo D2:D9 che abbiano valori superiori al valore presente in cella D3, si utilizza questa formula =CONTA.SE(D2:D9; “>” & D3)
Se desiderate contare le celle che contengono un operatore vero e proprio come parte del contenuto della cella, vale a dire i caratteri “>”, “<” o “=”, allora assieme all’operatore, nei criteri dovrete utilizzare un carattere jolly. Tali criteri saranno trattati come una stringa di testo invece che come un’espressione numerica. Ad esempio, la formula =CONTA.SE(D2:D9; “*>5*”) conterà tutte le celle dell’intervallo contenenti stringhe come “>5 giorni” oppure “>5 disponibili”.

Utilizzare la funzione CONTA.SE di Excel con le date

Se volete contare le celle con le date che sono maggiori, minori o uguali ad una data specificata o alla data presente in un’altra cella, si procede come abbiamo già visto. Tutte le formule qua sopra funzionano per le date così come per i numeri. Permettetemi di fare solo alcuni esempi:

CriterioFormula di esempioDescrizione
Contare le date uguali alla data specificata=CONTA.SE(B2:B10; “6/1/2016”)Conta il numero di celle dell’intervallo B2:B10 con la data 6-gen-2016
Contare le date maggiori o uguali ad un’altra data=CONTA.SE(B2:B10; “>=6/1/2016”)Conta il numero di celle dell’intervallo B2:B10 con le date maggiori o uguali al 6-gen-2016
Contare le date maggiori o uguali ad una data presente in un’altra cella, meno x giorni=CONTA.SE(B2:B10; “>=”&B2-“7”)Conta il numero di celle dell’intervallo B2:B10 con una data che sia maggiore o uguale a quella presente in B2 meno 7 giorni

Oltre a questi usi comuni, è possibile utilizzare la funzione CONTA.SE in combinazione con specifiche funzioni di data e ora di Excel come OGGI() per contare le celle in base alla data corrente.

CriterioFormula di esempio
Contare date uguali alla data corrente=CONTA.SE(A2:A10; OGGI())
Contare le date precedenti a oggi=CONTA.SE(A2:A10; “<“&OGGI())
Contare le date successive ad oggi=CONTA.SE(A2:A10; “>”&OGGI())
Contare le date che capitano tra una settimana=CONTA.SE(A2:A10; “=”&OGGI()+7)
Contare le date all’interno di uno specifico intervallo di date=CONTA.SE(B2:B10; “>=7/6/2016”)-CONTA.SE(B2:B10; “>1/6/2016”)

CONTA.SE con criteri multipli

In realtà, la funzione di Excel CONTA.SE non è esattamente progettata per il conteggio delle celle in base a più criteri. C’è un’altra funzione, CONTA.PIÙ.SE, progettata appositamente per questo (che sarà il tema di un prossimo articolo). Tuttavia, è possibile utilizzare CONTA.SE per contare valori sulla base di due o più criteri aggiungendo o sottraendo diverse funzioni CONTA.SE.

Esempio 1. CONTA.SE con due condizioni per i numeri

Una delle applicazioni più comuni della funzione CONTA.SE di Excel con 2 criteri è il conteggio dei numeri in un intervallo specifico, vale a dire meno di X, ma maggiore di Y. Ad esempio, è possibile utilizzare la seguente formula per contare le celle dell’intervallo B2:B9 dove un valore è maggiore di 5 e minore di 15.

=CONTA.SE(C2:C14; ">5")-CONTA.SE(C2:C14; ">=15")

Una formula CONTA.SE con 2 criteri per contare i numeri all'interno di un intervallo

Esempio 2. CONTA.SE con più condizioni per i valori di testo

Consideriamo un altro esempio con la funzione CONTA.SE che conterà 2 diversi valori di testo. Supponiamo di avere una lista della spesa e che vogliamo scoprire quante bevande analcoliche siano incluse. Ecco la formula che ce lo dice:

=CONTA.SE(B2:B12; "Limonata")+CONTA.SE(B2:B12; "Succo*")

Vi invito a prestare attenzione al carattere jolly (*) nel secondo criterio, che è usato per contare tutti i tipi di succo di frutta sulla lista.

Una formula CONTA.SE per contare 2 diversi valori di testo

Utilizzare la funzione CONTA.SE per trovare valori duplicati e valori univoci

Un altro possibile utilizzo della funzione CONTA.SE in Excel è per la ricerca di duplicati in una colonna, tra due colonne, o in una riga.

Esempio 1. Trovare e contare i duplicati in 1 colonna

Ad esempio, questa semplice formula =CONTA.SE($B$2:$B$13; B2)>1 identificherà tutte le voci duplicate nell’intervallo B2:B10, mentre un’altra funzione =CONTA.SE(C2:C13; VERO) vi dirà quanti doppioni ci sono:

Formula CONTA.SE per trovare e contare duplicati in una colonna

Esempio 2. Contare i duplicati tra due colonne

Se avete due liste separate, ad esempio due elenchi di nomi nelle colonne B e C, e volete sapere quanti nomi appaiono in entrambe le colonne, è possibile utilizzare CONTA.SE in combinazione con la funzione MATR.SOMMA.PRODOTTO per contare i duplicati:

=MATR.SOMMA.PRODOTTO((CONTA.SE(B2:B1000; C2:C1000)>0)*(C2:C1000<>""))

Possiamo anche fare un passo ulteriore e contare quanti nomi univoci ci sono in colonna C, vale a dire i nomi che non compaiono in colonna B:

=MATR.SOMMA.PRODOTTO((CONTA.SE(B2:B1000; C2:C1000)=0)*(C2:C1000<>""))

Una formula CONTA.SE per contare i valori univoci tra 2 colonne

SUGGERIMENTI
Se volete evidenziare celle duplicate o intere righe contenenti voci duplicate, è possibile creare regole di formattazione condizionale basate sulle formule CONTA.SE, come dimostrato in questo tutorial – Formattazione condizionale formule per evidenziare i duplicati

Esempio 3. Contare i duplicati e i valori univoci in una riga

Se desiderate contare i duplicati o i valori univoci in una certa riga, invece che in una colonna, utilizzate una delle formule seguenti. Queste formule possono essere utili, ad esempio, per analizzare lo storico dei sorteggi della lotteria.

Contare i duplicati in una riga:

=MATR.SOMMA.PRODOTTO((CONTA.SE(A2:I2; A2:I2)>1)*(A2:I2<>""))

Contare valori univoci in una riga:

=MATR.SOMMA.PRODOTTO((CONTA.SE(A2:I2; A2:I2)=1)*(A2:I2<>""))

Formula CONTA.SE per contare duplicati e valori univoci in una riga

CONTA.SE – Domande frequenti e problemi

Spero che questi esempi vi abbiano aiutato a prendere confidenza con la funzione CONTA.SE di Excel. Se avete provato una qualsiasi delle suddette formule su dati reali e qualcosa non ha funzionato, vi invito a consultare i seguenti 5 problemi più comuni. C’è una buona probabilità che troverete lì la risposta o un suggerimento utile.

CONTA.SE su un intervallo non contiguo di celle

Domanda: Come posso usare CONTA.SE di Excel su un intervallo non contiguo o una selezione di celle?

Risposta: CONTA.SE non funziona su intervalli non adiacenti, né la sua sintassi permette di specificare più celle singole come primo parametro. Invece, è possibile utilizzare una combinazione di diverse funzioni CONTA.SE:

  • Sbagliato: =CONTA.SE(A2; B3; C4; “>0”)
  • Giusto: =CONTA.SE(A2; “>0”) + CONTA.SE(B3; “>0”) + CONTA.SE(C4; “>0”)

Un modo alternativo si ottiene usando la funzione INDIRETTO per creare una serie di intervalli. Ad esempio, entrambe le formule seguenti producono lo stesso risultato che si vede nello screenshot:

=SOMMA(CONTA.SE(INDIRETTO({"C2:C8"."D2:D8"});"=0"))
=CONTA.SE($C2:$C8; 0) + CONTA.SE($D2:$D8; 0)

Una formula CONTA.SE per contare numeri in un intervallo non contiguo

E commerciale e virgolette nelle formule CONTA.SE

Domanda: Quando ho bisogno di usare una e commerciale in una formula CONTA.SE?

Risposta: Questa è probabilmente la parte più arcana. Personalmente trovo la sintassi della funzione CONTA.SE molto confusa, ma se vi soffermate un attimo, vedrete che ha un briciolo di ragionamento. La e commerciale e le virgolette sono necessarie per costruire una stringa di testo per l’argomento. Quindi, potete seguire queste regole:

  • Se usate un numero o un riferimento di cella nei criteri con corrispondenza esatta, non è necessaria né la e commerciale né le virgolette, per esempio =CONTA.SE(A1:A10; 10) oppure =CONTA.SE(A1:A10; C1)
  • Se i criteri includono del testo, un carattere jolly o un operatore con un numero, occorre racchiuderli tra virgolette, ad esempio =CONTA.SE(A2:A10; “limoni”) oppure =CONTA.SE(A2:A10; “*”) oppure =CONTA.SE(A2:A10; “>5”)
  • Se si utilizza un’espressione con un riferimento di cella o ad un’altra funzione di Excel, è necessario utilizzare le virgolette (“”) per avviare una stringa di testo e una e commerciale (&) per concatenare e finire la stringa. Ad esempio, =CONTA.SE(A2:A10; “>” & D2) oppure =CONTA.SE(A2:A10; “<=” & OGGI()).

Se siete in dubbio sulla necessità di una e commerciale, provate entrambi i modi. Nella maggior parte dei casi una e commerciale funziona bene, ad esempio, la formula =CONTA.SE(C2:C8; “<= 5”) e =CONTA.SE(C2:C8; “<=” & 5) funzionano ugualmente bene.

CONTA.SE per colore celle

Domanda: Come faccio a contare le celle per colore di riempimento o per colore del carattere piuttosto che in base ai valori?

Risposta: Purtroppo, la sintassi della funzione di CONTA.SE di Excel non permette di utilizzare i formati come condizione. L’unico modo possibile per contare o sommare le celle in base al loro colore è quella di usare una macro, o più precisamente una funzione definita dall’utente (UDF). Trovate il codice di lavoro per contare le celle colorate manualmente, così come per le celle formattate condizionalmente in questo articolo – Come contare e sommare le celle in base al loro colore.

L’errore #NOME? nelle formule CONTA.SE

Problema: La mia formula CONTA.SE genera un errore #NOME?. Come posso sistemarlo?

Risposta: Molto probabilmente, avete fornito un intervallo non corretto alla formula. Vi invito a verificare punto 1 qua sopra.

La formula CONTA.SE non funziona

Problema: La mia formula CONTA.SE non funziona! Cosa ho fatto di sbagliato?

Risposta: Se avete scritto una formula che è apparentemente corretta, ma non funziona o produce un risultato sbagliato, iniziate controllando le cose più ovvie, come un intervallo, le condizioni, i riferimenti di cella, l’uso della e commerciale e delle virgolette.

State molto attenti con l’utilizzo degli spazi nelle formule CONTA.SE. Nel creare una delle formule per questo articolo sono stato sul punto di strapparmi i pochi capelli che ho, perché la formula corretta (e sapevo con certezza che era giusta!) non funzionava. Come avrei poi scoperto, il problema risiedeva in un misero spazio inserito da qualche parte nel mezzo, Argh … Per esempio, guardate questa formula =CONTA.SE(B2:B13; ” Limonata”). A prima vista, non c’è nulla di strano, ad eccezione di uno spazio aggiuntivo dopo le virgolette di apertura. Microsoft Excel accetta la formula senza un messaggio di errore, di avviso o qualsiasi altra indicazione, supponendo che si voglia veramente contare le celle contenenti la parola ” Limonata” con uno spazio iniziale.

Se utilizzate la funzione CONTA.SE con criteri multipli, dividete la formula in più pezzi e verificate ogni funzione individualmente.

E questo è tutto per oggi. Nel prossimo articolo, esploreremo diversi modi per contare le celle in Excel con condizioni multiple. Spero di avervi qui la prossima settimana e grazie per la lettura!

Aspetta! Potrebbe interessarti anche: