fbpx

#Excel – Come ottenere il nome completo del foglio di lavoro

Ottenere il percorso, il nome della cartella e del foglio di lavoro

Se volete ottenere il percorso completo, il nome della cartella di lavoro e il foglio corrente con una formula, è possibile utilizzare la funzione CELLA e un riferimento a qualsiasi cella del lavoro:

=CELLA("nomefile";A1)

CELLA restituirà il nome in questo formato:

percorso[cartella.xlsx]foglio

Ottenendo un risultato simile a questo:

C:\Users\Simone\Desktop\[La funzione CELLA.xlsx]Foglio1

Notate che è necessario salvare il foglio di lavoro, al fine di ottenere il risultato.

Una nota in merito all’argomento rif (il secondo argomento della funzione)

La funzione CELLA ha un secondo argomento opzionale chiamato “rif”. Se “rif” non è fornito, CELLA restituirà il nome dell’attuale “foglio attivo” che può essere, ma anche non essere il foglio in cui è stata inserita la formula, e potrebbe anche essere in una cartella di lavoro diversa. Per eliminare la confusione, è fornite pure A1 come riferimento.

A volte però, ottenere tutte queste informazioni potrebbe sembrare eccessivo. Vedremo quindi nei paragrafi seguenti come ottenere solo una parte di queste informazioni.

Ottenere l’indirizzo della directory dove è situata la cartella di lavoro

Se volete ottenere solo l’indicazione della directory in cui si trova la cartella di lavoro, è possibile farlo con la seguente formula che utilizza le funzioni SINISTRA e TROVA:

=SINISTRA(CELLA("nomefile";A1);TROVA("[";CELLA("nomefile";A1))-1)

Il risultato sarà simile a questo:

C:\Users\Simone\Desktop\

Come funziona la formula

Il percorso completo del file è dato in pasto alla funzione SINISTRA, che viene utilizzata per estrarre solo il percorso completo della directory.

Il numero di caratteri da estrarre è individuato cercando con TROVA la posizione della parentesi quadra sinistra “[” e sottraendo 1:

TROVA("[";CELLA("nomefile";A1))-1

Ottenere solo il nome della cartella di lavoro

Se volete ottenere solo il nome della cartella di lavoro (quindi il nome del file, senza percorso o nome del foglio) è possibile farlo con una formula piuttosto lunga che utilizza le funzioni STRINGA.ESTRAI e la funzione TROVA:

=STRINGA.ESTRAI(CELLA("nomefile";A1);TROVA("[";CELLA("nomefile";A1))+1;TROVA("]"; CELLA("nomefile";A1))-TROVA("[";CELLA("nomefile";A1))-1)

Il risultato finale sarà simile a questo:

La funzione CELLA.xlsx

Come funziona la formula

STRINGA.ESTRAI, la funzione più esterna, semplicemente estrae il nome del file dal percorso. La posizione iniziale viene calcolata con TROVA:

TROVA("[";CELLA("nomefile";A1))+1

Il numero di caratteri da estrarre vengono calcolati anch’essi con TROVA:

TROVA("]";CELLA("nomefile";A1))-TROVA("[";CELLA("nomefile";A1))-1

Ottenere il percorso e il nome della cartella di lavoro senza il foglio

Se volete ottenere il nome completo e il percorso della cartella di lavoro corrente senza il nome del foglio, è possibile utilizzare una formula che utilizza diverse funzioni di testo per rimuovere il nome del foglio:

=SOSTITUISCI(SINISTRA(CELLA("nomefile";A1);TROVA("]";CELLA("nomefile";A1))-1);"[";"")

Il risultato finale sarà una stringa di testo che assomiglia a questa:

C:\Users\Simone\Desktop\La funzione CELLA.xlsx

Come funziona la formula

La funzione SINISTRA riceve il percorso completo come testo, insieme con la posizione della parentesi quadra “]” (meno 1) calcolata dalla funzione TROVA:

TROVA("]";CELLA("nomefile";A1))

Con questi argomenti, SINISTRA rimuove efficacemente il nome del foglio dal percorso. Tuttavia, la parentesi quadra sinistra “]” rimane:

percorso[cartella.xlsx

L’ultima funzione, SOSTITUISCI, rimuove la parentesi “]” sostituendola con una stringa vuota (“”).

=SOSTITUISCI(percorso[cartella.xlsx;"[";"")

Ottenere solo il nome del foglio

Se volete ottenere solo il nome del foglio (senza il nome del file o il percorso) è possibile farlo con una formula piuttosto lunga che utilizza le funzioni STRINGA.ESTRAI e TROVA:

=STRINGA.ESTRAI(CELLA("nomefile";A1);TROVA("]";CELLA("nomefile";A1))+1;255)

Il risultato finale sarà simile a questo:

Foglio1

Come funziona la formula

Il nome del file completo, più il percorso e il nome de foglio vengono dati in pasto alla funzione STRINGA.ESTRAI, che viene utilizzata per estrarre solo il nome del foglio.

La posizione iniziale viene calcolata con TROVA:

TROVA("]";CELLA("nomefile";A1))+1

Il numero di caratteri da estrarre viene fornito come 255. Nell’interfaccia utente di Excel, ad un foglio non è possibile dare un nome più lungo di 31 caratteri, ma il formato stesso del file permette nomi di foglio di lavoro fino a 255 caratteri.

 

LE SCHEDE TECNICHE DELLE FUNZIONI UTILIZZATE

Aspetta! Potrebbe interessarti anche: